2013年11月27日


管理者として実行を強制し、ANHTTPD を実行し、MySQLサービスを起動し、 エクスプローラで ANHTTPD のディレクトリを開け、ブラウザで、ANHTTPD の仮想ディレクトリを開くスクリプト

昔、『開発始めますよスクリプト』と読んでいました。当時は、管理者で実行とか必要なかったですが、今はたぶんサービスの実行で権限を求められると思います。
' 管理者として実行を強制する
Set obj = Wscript.CreateObject("Shell.Application")
if Wscript.Arguments.Count = 0 then
	obj.ShellExecute "wscript.exe", WScript.ScriptFullName & " runas", "", "runas", 1
	Wscript.Quit
end if

' MySQL サービスの表示名(DisplayName)
Dim MySQL_Name : MySQL_Name = "MySQL56"
' ANHTTPD のインストールディレクトリ
Dim Httpd_Path : Httpd_Path = "c:\httpd142p"
' ANHTTPD の常に使う仮想パス
Dim Httpd_VPath : Httpd_VPath = "http://localhost"
' ブラウザのパス
Dim Browser_Path : Browser_Path = "C:\Program Files\Google\Chrome\Application\chrome.exe"


' **********************************************************
' アプリケーション起動用
' **********************************************************
Set WshShell = Wscript.CreateObject( "WScript.Shell" )

' **********************************************************
' プロセス( httpd.exe ) を開始
' **********************************************************
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colProcesses = objWMIService.ExecQuery("Select * from Win32_Process Where Name = 'httpd.exe'") 
flg = false
For Each objProcess in colProcesses 
	flg = true
Next
if Not flg then
	WshShell.CurrentDirectory = Httpd_Path
	WshShell.Run( "httpd.exe" )
end if

' **********************************************************
' サービス( MySQL )
' **********************************************************
Set colRunningServices = objWMIService.ExecQuery("Select * from Win32_Service Where DisplayName = '" & MySQL_Name & "'") 
For Each objService in colRunningServices 
	if objService.State = "Stopped" then
		objService.StartService()
	end if
Next 

' **********************************************************
' ANHTTPD のインストールディレクトリをエクスプローラで開く
' **********************************************************
str = "explorer.exe /e," & Httpd_Path
WshShell.Run( str )


' **********************************************************
' ANHTTPD の常に使う仮想パス Google Chrome 
' **********************************************************
str = """" & Browser_Path & """"  & Httpd_VPath
WshShell.Run( str )



posted by at 05:36 | Comment(0) | ツール | このブログの読者になる | 更新情報をチェックする


この記事へのコメント
コメントを書く
お名前:

ホームページアドレス:

コメント:

認証コード: [必須入力]


※画像の中の文字を半角で入力してください。
※ブログオーナーが承認したコメントのみ表示されます。